Hebdogiciel n°107 à 108

 

1 !***********************!
2 !
LE DEMON D'EXELVISION !
3 ! (C) MEYNADIER L. 1985 !
4 !***********************!
46 !
47 CALL CHAR(65,"001F3F7FFF484840404")
48 CALL CHAR(66,"00F8FCFEFF1212020202")
49 CALL CHAR(67,"0000000106186")
50 CALL CHAR(68,"00784846A22478")
51 CALL CHAR(69,"000002020202020202")
52 CALL CHAR(70,"022222320A070728302")
53 CALL CHAR(71,"080838408000884838")
54 CALL CHAR(72,"010A060508081010102")
55 CALL CHAR(73,"204040808")
56 CALL CHAR(74,"3C7E3C18183C7E7E7EFF")
57 CALL CHAR(75,"5DFFC051D151DD40FF5D")
58 CALL CHAR(76,"BAFF0213B2531203FFBA")
59 CALL CHAR(77,"00102428102824241814")
60 CALL CHAR(78,"242830505048281864FF")
61 CALL CHAR(79,"03070F000E0723707F6F")
62 CALL CHAR(80,"C0E0F000F0E0C40EFEF6")
63 CALL CHAR(81,"076763620043874E4C0C")
64 CALL CHAR(82,"F0F6E64600E2F371303")
65 CALL CHAR(83,"0C0018000C0C0C08183")
66 CALL CHAR(84,"3000180030303010180C")
67 CALL CHAR(85,"000000000000033F7F")
68 CALL CHAR(86,"000000000107FFFE8")
69 CALL CHAR(87,"0E1535FECEB8C")
70 CALL CHAR(88,"080C0B094DE7F0FFEFE3")
71 CALL CHAR(89,"1030D090B2E70FFFF7C7")
72 CALL CHAR(90,"E3E3A1A1A3A60C0C083")
73 CALL CHAR(97,"E7E78585C5E53030100C")
74 CALL CHAR(98,"08081010001818181818")
75 CALL CHAR(99,"003C181008100810087E")
76 CALL CHAR(100,"FFFF7E3C3E3E7EFF")
77 CALL CHAR(101,"030F3F00030F3FFF")
78 CALL CHAR(102,"C0F0FC00C0F0FCFF")
79 CALL CHAR(103,"010307070F1F3F3F7FFF")
80 CALL CHAR(104,"80C0E0E0F0F8FCFCFEFF")
81 !
82 !
83 !
84 CLS "MBb":RANDOMIZE:CALL COLOR("1CB")
85 LOCATE (11,36):PRINT "OP"
86 PRINT TAB(36)"QR"
87 PRINT TAB(36)"ST"
88 CALL COLOR("0RBLF")
89 LOCATE (11,2):PRINT "LLee  ddeemmoonn  dd''"
90 LOCATE (13,13):PRINT "EEXXEELLVVIISSIIOONN"
91 CALL COLOR("0WB")
92 LOCATE (20,2):PRINT "(C) MEYNADIER Ludovic___ 1985"
93 CALL COLOR("0MB")
94 LOCATE (2,1):PRINT "Les regles (1=Oui 0=Non) ?"
95 A$=KEY$:IF A$<>"0"AND A$<>"1" THEN 95
96 IF A$="0" THEN CLS:END
97 !
98 !
99 !
100 CALL COLOR("0RY"):CLS:CALL HRON("B",5,1)
101 LOCATE (1,1):PRINT RPT$(" ",160)
102 LOCATE (2,2):PRINT "Le demon d'       (C)  1985)"
103 PRINT TAB(7)"EXELVISION     MEYNADIER L.":CALL COLOR("1RY")
104 LOCATE (2,37):PRINT "b"
105 LOCATE (3,37):PRINT "c"
106 CALL COLOR("0CB")
107 PRINT:PRINT "  Ce jeu consiste a tenter de sortir d'"
108 PRINT "un chateau, hante par le demon de la"
109 PRINT "contree d'EXELVISION. Ce dernier vous a"
110 PRINT "transporte, alors que vous etiez incon-"
111 PRINT "scient,dans une salle du chateau qui se"
112 PRINT "trouve assez eloignee de l'unique et"
113 PRINT "seule sortie. BON COURAGE ..."
114 PRINT:PRINT "Surveillez bien vos pts vie & vivres"
115 PRINT "ainsi que l'orientation de la salle"
116 PRINT "pour mieux vous deplacer de salle en"
117 PRINT "salle.Surtout n'oubliez jamais l'espace"
118 PRINT "entre le verbe & le mot lors des ordres"
119 PRINT:CALL COLOR("0WB"):PRINT TAB(10)"Tapez sur une touche"
120 A$=KEY$:CLS
121 CALL COLOR("0CB"):LOCATE (7,1)
122 PRINT "  Pour vous deplacer, vous devrez taper"
123 PRINT "un verbe suivi d'un espace et du mot"
124 PRINT "correspondant; Puis frapper sur ENTREE"
125 PRINT "Exemple:ALLER EST(entree)"
126 PRINT:PRINT "Liste des verbes : _ MANGER  _ PRENDRE"
127 PRINT " _ APPROCHER  _ DONNER    _ POSER"
128 PRINT " _ PLEURER    _ COMBATTRE _ FUIR"
129 PRINT " _ BOIRE      _ RIGOLER   _ UTILISER"
130 PRINT " _ ECLAIRER   _ ETEINDRE  _ ALLER"
131 CALL COLOR("0WB"):PRINT:PRINT TAB(10)"Tapez sur une touche":A$=KEY$
132 CLS:CALL COLOR("0CB"):LOCATE (7,1)
133 PRINT "  Liste des mots :":PRINT
134 PRINT " _ HACHE   _ ELEXIR   _ MARSEILLAISE"
135 PRINT " _ STATUE  _ MONSTRE  _ PORTE"
136 PRINT " _ TABLE   _ TABLEAU  _ ARMURE"
137 PRINT " _ EPEE    _ SALLE    _ LAMPE"
138 PRINT " _ EST     _ 0UEST    _ FANTOME"
139 PRINT " _ VASE    _ LUSTRE   _THRILLER"
140 PRINT " _ NORD    _ SUD ..."
141 PRINT "Nous vous conseillons de noter tous les"
142 PRINT "mots & verbes pour mieux vous vous en rappeler"
143 PRINT:CALL COLOR("0WB"):PRINT "Vous n'avez plus qu'a charger la 2eme"
144 PRINT "partie apres avoir tape une touche":A$=KEY$


2ème partie:


1 !***********************!
2 ! LE DEMON D'EXELVISION !
3 ! (C) MEYNADIER L. 1985 !
5 !     2eme partie       !
6 !***********************!
13 !     
15 CLS "BMb":RANDOMIZE:CALL HRON("M",14,1):GOSUB 19:GOTO 32
17 !
19 CALL COLOR("0GG"):LOCATE (1,1)
20 PRINT RPT$(" ",240);RPT$(" ",240)
21 CALL COLOR("0YY"):FOR Y=1 TO 12
22 LOCATE (Y,1):PRINT RPT$(" ",5)
23 LOCATE (Y,36):PRINT RPT$(" ",5)
24 NEXT:CALL COLOR("1RY")
25 FOR Y=1 TO 5:LOCATE (Y+7,Y+(6-Y*2))
26 PRINT "g"&RPT$(CHR$(160),28+Y*2)&"h":NEXT
27 CALL COLOR("0BM"):LOCATE (13,10)
28 PRINT "Le demon d'EXELVISION":RETURN
30 !
32 LOCATE (15,1):PRINT "   Vous devez choisir les capacites de"
33 PRINT "votre personnage: pts vie, pts force,"
34 PRINT "et pts vivre. Ces pts allant de 1 a 10."
35 PRINT "Le total de ces points ne devra pas"
36 PRINT "exceder 21. Selon votre choix, votre"
37 PRINT "personnage sera dans une categorie, ex:"
38 PRINT "chevalier, mage ..etc..."
39 CALL COLOR("0MB"):LOCATE (22,10):PRINT "Tapez une touche ..."
40 A$=KEY$:CLS:CALL POKE(50688,165,8,6,10):CALL POKE(49156,198)
42 !
44 CALL COLOR("0BM"):LOCATE (16,2):PRINT "Pts vie:";
45 ACCEPT VALIDATE(NUMERIC)SIZE(2),VIE
46 IF VIE<1 OR VIE>10 THEN 44
47 LOCATE (18,2):PRINT "Pts force:";
48 ACCEPT VALIDATE(NUMERIC)SIZE(2),FRC
49 IF FRC<1 OR FRC>10 THEN 47
50 LOCATE (20,2):PRINT "Pts Vivre:";
51 ACCEPT VALIDATE(NUMERIC)SIZE(2),VIV
52 IF VIV<1 OR VIV>10 THEN 50
53 IF VIE+FRC+VIV<>21 THEN 44
55 !
57 Q$="VALET":ELE1,PREH,PRES,PRET,PREU,PREA,PREE,PREL,PREV,ECLL,ELEX,MOTS=0
58 IF VIV<7 AND FRC<7 THEN Q$="PAYSAN"
59 IF FRC<7 AND VIE<7 THEN Q$="MAGE"
60 IF VIE<7 AND VIV<7 THEN Q$="NAIN"
61 IF VIE=VIV AND VIV=FRC THEN Q$="CHEVALIER"
62 LOCATE (21,2):PRINT "Nom du personnage que vous incarnez :"
63 LOCATE (22,15):ACCEPT VALIDATE(UALPHA)SIZE(10)BEEP,NOM$
65 !
67 OR$="NORD":GOSUB 238
68 CALL SOUND(5):GOSUB 264
69 GOSUB 269:DEVA,SALLE=1
70 S$="SALLE VIDE"
71 GOSUB 280:GOSUB 297
72 GOSUB 275:IF SALLE=2 THEN 73 ELSE 68
73 CLS:GOSUB 19:OR$="NORD"
74 S$="SALLE VIDE":IF PREA=1 THEN 77
75 CALL COLOR("1BG"):LOCATE (5,20):PRINT "OP":LOCATE (6,20):PRINT "QR"
76 LOCATE (7,20):PRINT "ST":S$="VISION : UNE ARMURE"
77 GOSUB 269:PRE,DROI,GAUC,ARMU=1
78 IF PREA=1 THEN ARMU,PRE=0
79 GOSUB 245:GOSUB 254
80 GOSUB 465
81 IF SALLE=0 THEN 84
82 IF SALLE=4 THEN 91
83 GOTO 80
84 GOSUB 269:EPEE,DROI,PRE=1:S$="VISION : EPEE"
85 GOSUB 19:GOSUB 254:OR$="NORD"
86 IF PREE=1 THEN EPEE,PRE=0:S$="SALLE VIDE":GOTO 89
87 CALL COLOR("1BG"):LOCATE (7,20):PRINT "H":LOCATE (8,20):CALL COLOR("1BR")
88 PRINT "I"
89 GOSUB 465
90 IF SALLE=2 THEN 73 ELSE 89
91 GOSUB 269:GAUC,DEVA=1:S$="SALLE VIDE":OR$="NORD"
92 GOSUB 19:GOSUB 245:GOSUB 264
93 GOSUB 465
94 IF SALLE=2 THEN 73
95 IF SALLE=5 THEN 97
96 GOTO 93
97 GOSUB 269:DEVA,ARRI,DROI=1:IF PREL=0 THEN LAMP,PRE=1
98 GOSUB 19:GOSUB 245:GOSUB 254:GOSUB 264
99 OR$="Attention c'est l'EST cette fois"
100 S$="SALLE VIDE":IF PREL=1 THEN 103
101 S$="VISION : LAMPE (bougie) ETEINTE":CALL COLOR("1YR"):LOCATE (10,20)
102 PRINT "b":LOCATE (11,20):PRINT "c"
103 GOSUB 465
104 IF SALLE=4 THEN 91
105 IF SALLE=7 THEN 108
106 IF SALLE=6 THEN 171
107 GOTO 103
108 GOSUB 269:GAUC,DROI,LUST=1
109 GOSUB 19:GOSUB 245:GOSUB 254:OR$="NORD":S$="VISION : UN VIEUX LUSTRE"
110 CALL COLOR("1BG"):LOCATE (1,20):PRINT "E":LOCATE (2,20):PRINT "FG"
111 GOSUB 465
112 IF SALLE=5 THEN 97
113 IF SALLE=9 THEN 115
114 GOTO 111
115 GOSUB 269:DEVA,ARRI,GAUC=1
116 GOSUB 19:GOSUB 245:GOSUB 254:GOSUB 264
117 S$="SALLE VIDE (d'interet)":OR$="OUEST (et non nord)"
118 GOSUB 465
119 IF SALLE=7 THEN 108
120 IF SALLE=10 THEN 144
121 IF SALLE=8 THEN 123
122 GOTO 118
123 GOSUB 269:DEVA,DROI=1:IF PREH=0 THEN HACH,PRE=1
124 GOSUB 19:GOSUB 254:GOSUB 264
125 OR$="NORD":S$="SALLE DESERTE":IF PREH=1 THEN 127
126 S$="VISION : UNE HACHE":CALL COLOR("1BR"):LOCATE (10,20):PRINT "CD"
127 GOSUB 465
128 IF SALLE=9 THEN 115
129 IF SALLE=10 THEN 131
130 GOTO 127
131 GOSUB 169:GAUC,ARRI=1
132 GOSUB 19:GOSUB 254:GOSUB 264
133 S$="SALLE SANS RIEN":OR$="Orientation SUD !"
134 GOSUB 465:IF SALLE=8 THEN 123
135 IF SALLE=9 THEN 137
136 GOTO 134
137 GOSUB 269:DEVA=1:IF PREV=0 THEN PRE,VASE=1
138 GOSUB 19:GOSUB 264:OR$="NORD"
139 S$="SALLE 'SEULE'":IF PREV=1 THEN 142
140 S$="VISION : UN VASE (qui s'ennuie)"
141 CALL COLOR("1GR"):LOCATE (9,20):PRINT "J":LOCATE (10,20):PRINT "d"
142 GOSUB 465:IF SALLE=10 THEN 131
143 GOTO 142
144 GOSUB 269:DEVA,ARRI,DROI=1
145 GOSUB 19:GOSUB 245:GOSUB 254:GOSUB 264
146 S$="SALLE VIDE":OR$="Vue EST !"
147 GOSUB 465:IF SALLE=9 THEN 115
148 IF SALLE=11 THEN 151
149 IF SALLE=12 THEN 157
150 GOTO 147
151 GOSUB 269:ARRI=1:IF PREM=0 THEN PRE,TABM=1
152 GOSUB 19:GOSUB 264:OR$="plein SUD ..."
153 S$="SALLE DESERTEMENT VIDE ...":IF PREM=1 THEN 155
154 S$="VISION : UN PETIT TABLEAU":CALL COLOR("1BG"):LOCATE (5,15):PRINT "KL"
155 GOSUB 465:IF SALLE=10 THEN 144
156 GOTO 155
157 GOSUB 269:GAUC,ARRI=1:IF PRET=0 THEN PRE,TABL=1
158 GOSUB 19:GOSUB 254:GOSUB 264:OR$="SUD"
159 S$="SALLE VIDE !":IF PRET=1 THEN 162
160 S$="VISION : UNE TABLE (modele mini)":CALL COLOR("1RB")
161 LOCATE (9,20):PRINT "AB"
162 GOSUB 465:IF SALLE=10 THEN 144
163 IF SALLE=11 THEN 165
164 GOTO 162
165 GOSUB 269:FANT,COM,DON,FUI,DEVA=1
166 GOSUB 19:GOSUB 264:OR$="NORD !!!"
167 CALL COLOR("1WG"):LOCATE (5,12):PRINT "UVW"
168 S$="VISION : D'HORREUR ... UN FANTOME"
169 GOSUB 465:IF SALLE=12 THEN S1$="IMPOSSIBLE DE SORTIR":SALLE=11:GOSUB 275
170 CALL SOUND(1):GOTO 169
171 CALL SOUND(Y):OR$="SUD"
172 GOSUB 269:GAUC,ARRI=1:IF ECLL=0 THEN GOSUB 179:GOTO 174
173 GOSUB 19:GOSUB 254:GOSUB 264:S$="SALLE VIDE":GOTO 176
174 S$="VOUS ETES DANS L'OBSCURITE":GOSUB 465:IF SALLE=5 THEN 97
175 IF ECLL=0 THEN 174 ELSE 173
176 GOSUB 465:IF SALLE=5 THEN 97
177 IF SALLE=4 THEN 181
178 GOTO 176
179 CALL COLOR("0BB"):LOCATE (1,1)
180 PRINT RPT$(" ",240);RPT$(" ",240):RETURN
181 IF ECLL=0 THEN 292
182 GOSUB 269:GAUC,DROI,DEVA=1:IF PRET=0 THEN PRE,TABL=1
183 GOSUB 19:GOSUB 245:GOSUB 254:GOSUB 264:OR$="NORD"
184 S$="SALLE VIDE":IF PRET=1 THEN 186
185 S$="VISION : UNE mini-TABLE":CALL COLOR("1BR"):LOCATE (9,20):PRINT "AB"
186 GOSUB 465:IF ECLL=0 THEN GOSUB 292
187 IF SALLE=6 THEN 171
188 IF SALLE=2 THEN 191
189 IF SALLE=5 THEN 201
190 GOTO 186
191 IF ECLL=0 THEN 292
192 GOSUB 269:DROI,BOI,ELEX=1
193 GOSUB 19:GOSUB 254:OR$="NORD"
194 S$="SALLE VIDE":IF ELE1=1 THEN ELEX,BOI=0:GOTO 197
195 S$="VISION : ELEXIR (a boire)"
196 CALL COLOR("1CR"):LOCATE (9,20):PRINT "J":LOCATE (10,20):PRINT "d"
197 GOSUB 465:IF ECLL=0 THEN 292
198 IF SALLE=4 THEN 181
199 IF ELE1=1 THEN ELEX,BOI=0
200 GOTO 197
201 GOSUB 269:ARRI,GAUC=1:IF PRES=0 THEN PRE,STAT=1
202 GOSUB 19:GOSUB 254:GOSUB 264:OR$="SUD"
203 S$="SALLE DESERTE":IF PRES=1 THEN 206
204 S$="VISION : STATUE":CALL COLOR("1WR"):LOCATE (9,20):PRINT "M"
205 LOCATE (10,20):PRINT "N"
206 GOSUB 465:IF ECLL=0 THEN 292
207 IF SALLE=4 THEN 181
208 IF SALLE=3 THEN 210
209 GOTO 206
210 GOSUB 269:MONS,COM,DON,FUI,GAUC,DROI=1
211 GOSUB 19:GOSUB 245:GOSUB 254:OR$="NORD"
212 S$="SALLE VIDE":IF MOTS=1 THEN 215
213 CALL COLOR("1BG"):LOCATE (6,20):PRINT "XY":LOCATE (7,20):PRINT "Za"
214 S$="VISION : AHHHH ! LE MONSTRE"
215 CALL SOUND(2):GOSUB 465:IF ECLL=0 THEN 292
216 IF MOTS=0 THEN 215
217 IF MOTS=1 THEN GOSUB 19:GOSUB 245:GOSUB 254:GOSUB 269:S$="":DROI,GAUC=1
218 IF S$="" THEN S$="SALLE SEULE"
219 IF SALLE=5 THEN 201
220 IF SALLE=1 THEN 222
221 GOTO 215
222 GOSUB 269:DROI,GAUC=1:OR$="NORD (sortie ouest)"
223 GOSUB 19:GOSUB 245:GOSUB 254
224 CALL COLOR("0CR"):S$="EN ALLANT A L'OUEST VOUS AVEZ GAGNE"
225 LOCATE (10,8):PRINT "<-"
226 GOSUB 465:IF SALLE=3 THEN 210
227 IF SALLE=-1 THEN 232
228 GOTO 226
230 !
232 CALL HROFF:CLS "Mbb":CALL COLOR("0MBLF")
233 LOCATE (12,13):PRINT "GGAAGGNNEE  !!"
234 CALL COLOR("0Cb"):GOTO 473
236 !
238 CLS:CALL COLOR("0BM"):LOCATE (15,1):PRINT "Nom : "&Q$&" "&NOM$
239 LOCATE (16,1):PRINT USING"Vie : ##  Force : ##  Vivre : ##",VIE,FRC,VIV
240 LOCATE (17,5):PRINT OR$:CALL COLOR("1BM"):LOCATE (17,2):PRINT "ef"
241 RETURN
243 !
245 CALL COLOR("1bY")
246 LOCATE (4,4):PRINT "g"
247 LOCATE (5,3):PRINT "g"&CHR$(160)
248 FOR Y=6 TO 9:LOCATE (Y,3):PRINT CHR$(160)&CHR$(160):NEXT
249 CALL COLOR("1Rb"):LOCATE (9,4):PRINT "g"
250 LOCATE (10,3):PRINT "g":RETURN
252 !
254 CALL COLOR("1bY"):LOCATE (4,37)
255 PRINT "h":LOCATE (5,37)
256 PRINT CHR$(160)&"h"
257 FOR Y=6 TO 9:LOCATE (Y,37):PRINT CHR$(160)&CHR$(160):NEXT
258 CALL COLOR("1Rb"):LOCATE (9,37)
259 PRINT "h":LOCATE (10,38):PRINT "h"
260 RETURN
262 !
264 CALL COLOR("0bb"):FOR Y=4 TO 7
265 LOCATE (Y,19):PRINT "    ":NEXT:RETURN
267 !
269 SAIS,MAN,PRE,DON,COM,FUI,ETE,BOI=0
270 ELEX,HACH,MONS,STAT,TABL,TABM,ARMU,EPEE,SALL,LAMP,GAUC,DROI,MARS,FANT=0
271 VASE,THRI,LUST,PORT,DEVA,ARRI=0:RETURN
273 !
275 CALL COLOR("0BM"):LOCATE (19,1):PRINT RPT$(" ",80):LOCATE (19,1)
276 PRINT S1$:PAUSE 5:S1$="":RETURN
278 !
280 CALL COLOR("0WM"):LOCATE (18,1):PRINT S$
281 LOCATE (21,1):CALL COLOR("0MB")
282 PRINT "  QUE FAITES-VOUS ?"
283 CALL COLOR("0BM"):LOCATE (22,1)
284 PRINT "ORDRE ->";:ACCEPT VALIDATE(UALPHA)SIZE(23),REP$
285 A=POS(REP$," ",1)
286 IF REP$="0"OR LEN(REP$)<9 OR A<6 THEN 283
287 VERB$=SEG$(REP$,1,A-1):MOT$=SEG$(REP$,A+1,LEN(REP$)-(LEN(VERB$)+1))
288 RETURN
290 !
292 GOSUB 179:GOSUB 465
293 IF ECLL=0 THEN 292 ELSE RETURN
295 !
297 CALL SOUND(10)
298 IF VERB$="MANGER" THEN S1$="IL N'Y A RIEN A MANGER ICI !":RETURN
299 IF VIE<1 OR VIV<1 OR FRC<1 THEN 469
300 IF VERB$="PRENDRE"AND PRE=0 THEN S1$="ON NE PEUT RIEN PRENDRE ...":RETURN
301 IF VERB$="APPROCHER" THEN 449
302 IF VERB$="DONNER"AND DON=0 THEN S1$="IL N'Y A PERSONNE !!":RETURN
303 IF VERB$="POSER" THEN 320
304 IF VERB$="BOIRE"AND BOI=0 THEN S1$="VOUS VOYEZ A BOIRE VOUS!":RETURN
305 IF VERB$="COMBATTRE"AND COM=0 THEN S1$="ON NE COMBAT PAS RIEN":RETURN
306 IF VERB$="COMBATTRE"AND COM=1 THEN S1$="EN UTILISANT QUOI !":RETURN
307 IF VERB$="RIGOLER"OR VERB$="PLEURER" THEN S1$="VOUS ETES EMOTIFS":RETURN
308 IF VERB$="FUIR"AND FUI=0 THEN S1$="IL N'Y A RIEN D'APPEURANT ...":RETURN
309 IF VERB$="CHANTER" THEN S1$="VOUS CHANTEZ BIEN "&MOT$:RETURN
310 IF VERB$="UTILISER" THEN 351
311 IF VERB$="ALLER" THEN 371
312 IF VERB$="ECLAIRER"AND PREL=0 THEN S1$="IL N'Y A RIEN A ECLAIRER":RETURN
313 IF VERB$="ECLAIRER"AND PREL=1 THEN 362
314 IF VERB$="ETEINDRE"AND PREL=0 THEN S1$="IL N'Y A RIEN A ETEINDRE":RETURN
315 IF VERB$="ETEINDRE"AND PREL=1 THEN 362
316 GOTO 389
318 !
320 DATA HACHE,STATUE,TABLE,TABLEAU,ARMURE,EPEE,LAMPE,VASE
321 RESTORE 320
322 A=0:FOR Y=1 TO 8:READ A$:IF MOT$=A$ THEN A=1
323 NEXT:IF A=0 THEN S1$="ON NE POSE PAS N'IMPORTE QUOI !":RETURN
324 IF MOT$="HACHE" THEN 338
325 IF MOTS="STATUE" THEN 336
326 IF MOT$="TABLE" THEN 334
327 IF MOT$="LAMPE" THEN 344
328 IF MOT$="TABLEAU" THEN 332
329 IF MOT$="VASE" THEN 346
330 IF MOT$="ARMURE" THEN 340
331 IF MOT$="EPEE" THEN 342
332 IF PREU=1 THEN PREU=0:S1$="VOUS N'AVEZ PLUS DE TABLEAU":RETURN
333 GOTO 347
334 IF PRET=1 THEN PRET=0:S1$="VOUS N'AVEZ PLUS DE TABLE":RETURN
335 GOTO 347
336 IF PRES=1 THEN PRES=0:S1$="VOUS N'AVEZ PLUS DE STATUE":RETURN
337 GOTO 347
338 IF PREH=1 THEN PREH=0:S1$="VOUS N'AVEZ PLUS DE HACHE":RETURN
339 GOTO 347
340 IF PREA=1 THEN PREA=0:S1$="VOUS N'AVEZ PLUS D'ARMURE":RETURN
341 GOTO 347
342 IF PREE=1 THEN PREE=0:S1$="VOUS N'AVEZ PLUS D'EPEE":RETURN
343 GOTO 347
344 IF PREL=1 THEN PREL=0:ECLL=0:S1$="PLUS DE LAMPE !":RETURN
345 GOTO 347
346 IF PREV=1 THEN PREV=0:S1$="VOUS N'AVEZ PLUS VOTRE VASE":RETURN
347 S1$="ON NE PEUT POSER QUELQUE CHOSE QUE L'ON A POINT...":RETURN
349 !
351 IF COM=0 THEN S1$="IL EST IDIOT D'UTILISER "&MOT$:RETURN
352 IF FANT=1 THEN S1$="IL NE CRAINT PAS "&MOT$:VIE=0:RETURN
353 IF MONS=1 AND MOT$="EPEE" THEN 356
354 IF MONS=1 AND MOT$="HACHE" THEN 356
355 S1$="NE ME TESTEZ PAS ! JE N'AIME PAS CA":RETURN
356 IF PREE=0 AND PREH=0 THEN S1$="N'AYANT PAS D'ARME :MORT!":VIE=0:RETURN
357 VIE=VIE-INTRND(3):IF VIE<1 THEN VIE=0:S1$="LE MONSTRE VOUS A EU":RETURN
358 S1$="VOUS AVEZ TUE LE MONSTRE !":MOTS=1:RETURN
360 !
362 IF MOT$<>"LAMPE" THEN S1$="ON N'ECLAIRE PAS N'IMPORTE QUOI !":RETURN
363 IF VERB$="ETEINDRE" THEN 366
364 IF ECLL=0 THEN ECLL=1:S1$="VOTRE LAMPE S'ALLUME":RETURN
365 IF ECLL=1 THEN S1$="ELLE EST DEJA ACLAIREE...":RETURN
366 IF ECLL=1 THEN ECLL=0:S1$="VOTRE LAMPE S'ETEIND":RETURN
367 IF ECLL=0 THEN S1$="ELLE EST ETEINTE !":RETURN
369 !
371 IF SALLE/3=INT(SALLE/3)THEN VIE=VIE-1
372 IF SALLE/5=INT(SALLE/5)THEN VIV=VIV-1
373 IF MOT$="NORD"AND DEVA=0 THEN 384
374 IF MOT$="SUD"AND ARRI=0 THEN 384
375 IF MOT$="EST"AND DROI=0 THEN 384
376 IF MOT$="OUEST"AND GAUC=0 THEN 384
377 IF MOT$<>"NORD"AND MOT$<>"SUD"AND MOT$<>"EST"AND MOT$<>"OUEST" THEN 383
378 IF MOT$="SUD" THEN SALLE=SALLE-1
379 IF MOT$="EST" THEN SALLE=SALLE+2
380 IF MOT$="NORD" THEN SALLE=SALLE+1
381 IF MOT$="OUEST" THEN SALLE=SALLE-2
382 RETURN
383 S1$="DONNEZ UN POINT CARDINAL AVEC LE VERBE ALLER !!!":RETURN
384 S1$="N'ESSAYEZ PAS DE ME TESTER !!! DONNEZ MOI UNE AUTRE DIRECTION"
385 RETURN
387 !
389 IF VERB$="PRENDRE"AND PRE=1 THEN 417
390 IF VERB$="FUIR" THEN 410
391 IF VERB$="BOIRE" THEN 402
392 IF VERB$="DONNER"AND DON=1 THEN 397
393 S1$="UTILISEZ LES VERBES QUE JE CONNAIS !":RETURN
395 !
397 IF FANT=1 THEN S1$="IL N'ACCEPTE RIEN !":VIE=VIE-1:FRC=FRC-2:RETURN
398 S1$="IL N'APPRECIE GUERE VOTRE OFFRE ...":VIE=VIE-1:RETURN
400 !
402 IF MOT$<>"ELEXIR" THEN S1$="ON NE BOIT PAS "&MOT$:RETURN
403 IF SAIS<>1 THEN S1$="APPROCHER-LE D'ABORD !":RETURN
404 VIE=VIE+INTRND(2):VIV=VIV+2+INTRND(3):S1$="L'ELEXIR VOUS RECONFORTE"
405 ELE1=1:CALL COLOR("0RR"):LOCATE (9,20):PRINT " ":LOCATE (10,20):PRINT " "
406 S$="SALLE VIDE":RETURN
408 !
410 IF MONS=1 THEN 413
411 IF FANT=1 THEN 413
412 RETURN
413 S1$="REACTION STUPIDE, VOUS ETES MASSACRER":VIE=0:FRC=0:RETURN
415 !
417 S1$="VOUS POSSEDEZ MAINTENANT :"
418 IF MOT$="HACHE"AND HACH=1 AND SAIS=1 THEN 442
419 IF MOT$="STATUE"AND STAT=1 AND SAIS=1 THEN 444
420 IF MOT$="TABLE"AND TABL=1 AND SAIS=1 THEN 427
421 IF MOT$="TABLEAU"AND TABM=1 AND SAIS=1 THEN 430
422 IF MOT$="ARMURE"AND ARMU=1 AND SAIS=1 THEN 432
423 IF MOT$="EPEE"AND EPEE=1 AND SAIS=1 THEN 435
424 IF MOT$="LAMPE"AND LAMP=1 AND SAIS=1 THEN 438
425 IF MOT$="VASE"AND VASE=1 AND SAIS=1 THEN 440
426 S1$="N'OUBLIEZ PAS D'APPROCHEZ L'OBJET AVANT DE VOUS EN SAISIR":RETURN
427 IF FRC<8 THEN S1$="VOUS ETES TROP FRELE POUR LA PRENDRE":RETURN
428 S1$=S1$&MOT$:PRET=1:S$="SALLE VIDE"
429 CALL COLOR("0RR"):LOCATE (9,20):PRINT "  ":RETURN
430 S1$=S1$&MOT$:PREM=1:CALL COLOR("0GG"):LOCATE (5,15):PRINT "  "
431 S$="SALLE DESERTE":RETURN
432 IF FRC<6 THEN S1$="ELLE EST TROP LOURDE POUR VOTRE FORCE":RETURN
433 CALL COLOR("0GG"):FOR Y=5 TO 7:LOCATE (Y,20):PRINT "  ":NEXT
434 S1$=S1$&MOT$:PREA=1:S$="SALLE VIDE":RETURN
435 S1$=S1$&MOT$:S$="SALLE VIDE":CALL COLOR("0GG")
436 LOCATE (7,20):PRINT " ":LOCATE (8,20):CALL COLOR("0RR")::PRINT " "
437 PREE=1:RETURN
438 S1$=S1$&MOT$:S$="SALLE VIDE":CALL COLOR("0RR")
439 LOCATE (10,20):PRINT " ":LOCATE (11,20):PRINT " ":PREL=1:RETURN
440 S1$=S1$&MOT$:S$="SALLE TRISTEMENT VIDE":CALL COLOR("0RR")
441 LOCATE (9,20):PRINT " ":LOCATE (10,20):PRINT " ":PREV=1:RETURN
442 S1$=S1$&MOT$:S$="SALLE VIDE":CALL COLOR("0RR")
443 LOCATE (10,20):PRINT "  ":PREH=1:RETURN
444 S1$=S1$&MOT$:S$="SALLE DESERTE":CALL COLOR("0RR")
445 LOCATE (9,20):PRINT " ":LOCATE (10,20):PRINT " ":PRES=1:RETURN
447 !
449 IF MOT$="HACHE"AND HACH=1 THEN S1$="ELLE EST EN BON ETAT":SAIS=1:RETURN
450 IF MOT$="PORTE" THEN S1$="C'EST UNE PORTE COMME UNE AUTRE":RETURN
451 IF MOT$="MONSTRE"AND MONS=1 THEN S1$="BEURK! QUEL HORREUR":RETURN
452 IF MOT$="ELEXIR"AND ELEX=1 THEN S1$="IL A L'AIR BON!":SAIS=1:RETURN
453 IF MOT$="STATUE"AND STAT=1 THEN SAIS=1:S1$="C'EST L'ART MODERNE !":RETURN
454 IF MOT$="TABLE"AND TABL=1 THEN SAIS=1:S1$="ELLE EST EN CHENE":RETURN
455 IF MOT$="TABLEAU"AND TABM=1 THEN SAIS=1:S1$="DE PEINTRE INCONNU !":RETURN
456 IF MOT$="ARMURE"AND ARMU=1 THEN S1$="ELLE EST SOLIDE":SAIS=1:RETURN
457 IF MOT$="EPEE"AND EPEE=1 THEN SAIS=1:S1$="BELLE LAME ...":RETURN
458 IF MOT$="LAMPE"AND LAMP=1 THEN SAIS=1:S1$="ELLE EST ETEINTE":RETURN
459 IF MOT$="FANTOME"AND FANT=1 THEN S1$="HORRIBLE ECTOPLASME ...":RETURN
460 IF MOT$="VASE"AND VASE=1 THEN SAIS=1:S1$="IL EST DE PORCELAINE":RETURN
461 IF MOT$="LUSTRE"AND LUST=1 THEN 463
462 S1$="IL N'Y A PAS A APPROCHER DANS LA SALLE DE "&MOT$&" ...":RETURN
463 S1$="IL EST BIEN ACCROCHE ET TIENT BIEN MAIS IMPOSSIBLE DE LE PRENDRE"
464 RETURN
465 GOSUB 238:GOSUB 280:GOSUB 297:GOSUB 275:RETURN
467 !
469 CALL HROFF:CLS "MBb":CALL COLOR("0WBHLF")
470 LOCATE (12,14):PRINT "MMOORRTT  !!"
471 LOCATE (13,14):PRINT "MMOORRTT  !!"
472 CALL COLOR("0MB")
473 LOCATE (20,4):PRINT "UNE AUTRE PARTIE ?(1=OUI 0=NON)"
474 A$=KEY$:IF A$="0" THEN CALL HROFF:CLS "BCC":END ELSE RUN
476 !
478 SUB SOUND(A)
479 FOR Y=260 TO 510 STEP A
480 CALL POKE(258,Y,132):NEXT
481 CALL POKE(259,45):SUBEND

Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.