1 !*********************
4 !
7 ! LE CLUEDO
10 ! EGNIME
13 !
16 !
19 ! FAIT LE 23/11/1985
22 !
25 ! PAR ERIC GUIGNARD
28 !
31 !*********************
34 !
37 ! DATA
40 !
43 RANDOMIZE
46 CALL POKE(50688,165,8,6,10):CALL POKE(49156,198,0)
49 CALL C
52 IMAGE "############### ############### #######"
55 DATA 2,6,AAABAAABAFABABAFDABAAA
58 DATA 3,6,ABBBABABAEABBBAEGABABB
61 DATA 4,6,AABBABBBABABABABBABAAA
64 DATA 5,6,ABBBABAJABABABABBABABB
67 DATA 6,6,AAABAAABABABABABBABAAA
70 DATA 4,29,BC,5,29,BA,6,29,DAFBH,7,29,EAAG
73 DATA 8,29,IAJ,9,29,IAJ,10,30,KK,11,30,KK
76 DATA 2,37,DAAF,3,37,ABBA,4,37,ABBA,5,39,DG,6,38,DG
79 DATA 7,38,A,8,38,A,10,38,A
82 DATA 1,1,10,6,1,16,11,7,12,1,7,7,12,12,15,7,1,31,8,18
85 DATA 1,1,39,7,2,3,7,8,2,8,16,2,8,20,5,8,27,2,7,32,8
88 DATA 12,2,6,13,13,3,13,18,5,13,25,4,14,33,7,20,1,39
91 DATA 2,2,10,2,17,12,19,2,6,19,13,15,2,33,7,13,33,7,19,33,7
94 DATA 1,1,20,1,7,7,1,12,7,1,16,8,1,22,8,1,28,8,1,32,4,1,40,20
97 DATA 12,8,2,15,8,6,13,12,7,13,20,7,13,28,7,7,32,3,11,32,4,16,32,4
100 DATA CUISINE,"DOC EDWARDS",POISON
103 DATA G.SALON,HELLEN,CHANDELIER
106 DATA VERANDA,"MISS BAXTER",COUTEAU
109 DATA BOUDOIR,"COLONEL ARTHUR",ACIDE
112 DATA BUREAU,EVA,POIGNARD
115 DATA SAM,"MR BLONDEL",REVOLVER
118 DATA P.SALON,"SHARA VOLMER",CORDE
121 DATA CAVE,"BOB WOLF",MATRAQUE
124 DATA LABO,AMELIE,"CLE ANGLAISE"
127 DATA WC,"LE GARDE",ELECTROCUTE
130 DATA,"MAITRE D'HOTEL",DROGUE
133 DATA,"VALERIE BLAKE",PENDAISON
136 DATA,"MIKE MILLER",ARSENIC
139 DATA,"ARCHIE SHEPP",GOURDIN
142 DATA,"EVE ROSS",ETRANGLEMENT
145 DATA,"JORDAN ROSS",DEFENESTRE
148 DATA,"ANNE GREY",HYDROCUTION
151 DATA,"BARRY JONES",SCORPION
154 DATA,MADAME,CHUTE
157 DATA,L'INFIRMIERE,BARBITURIC
160 DATA,"STEVE RILEY",CYANURE
163 DATA,"TOM BRADFORD",HACHE
166 DATA,MONSIEUR,SUICIDE
169 !
172 ! GRAPHIQUE
175 !
178 CALL CHAR(65,"FF00FF00FF00FF00FF00")
181 CALL CHAR(66,"00")
184 CALL CHAR(67,"00000007000F003F00FF")
187 CALL CHAR(68,"05050505151555555555")
190 CALL CHAR(69,"55555515150505010101")
193 CALL CHAR(70,"808080A0A0A8A8AAAAAA")
196 CALL CHAR(71,"AAAAAAAAA8A8A0A08080")
199 CALL CHAR(72,"000000FFAAAAB0A0A0A0")
202 CALL CHAR(73,"05050505050505050505")
205 CALL CHAR(74,"A8A8A8A8A8A8A8A8A8A8")
208 CALL CHAR(75,"F000F000F000F000F0F0")
211 CALL CHAR(76,"AA55AA55AA55AA55AA55")
214 CALL CHAR(100,"7EFFDBDB183C66C3E7FF")
217 CALL CHAR(105,"FF222222FF080808FF22")
220 CALL CHAR(97,"0018183C5A9918244281")
223 CALL CHAR(10,"00000000181800000000")
226 CALL CHAR(11,"00001818000018180000")
229 CALL CHAR(12,"00606000181800060600")
232 CALL CHAR(13,"00666600000000666600")
235 CALL CHAR(14,"00666600181800666600")
238 CALL CHAR(15,"00666600666600666600")
241 !
244 ! LES PHRASES
247 !
250 DIM S$(44)
253 S$(10)="# MONSIEUR A ETE ASSASSINE #"
256 S$(11)="Demasquez son assassin !!!"
259 S$(12)="MAIS attention ... "
262 S$(13)="L'erreur est FATALE "
265 S$(14)=" BONNE CHANCE !!! "
268 S$(15)="LA REGLE (1=OUI/0=NON) : "
271 S$(16)="LA LISTE (1=OUI/0=NON) : "
274 S$(17)="OU ETES VOUS "
277 S$(18)="L'ARME DU CRIME "
280 S$(19)="L'ASSASSIN "
283 S$(20)="AUCUN INDICE "
286 S$(21)="UN INDICE SEULEMENT ! "
289 S$(22)="2 INDICES C'EST BIEN ! "
292 S$(23)="LIEU DU CRIME "
295 S$(24)="C'EST SIMPLE, NON !!! "
298 S$(25)="VIEUX GRIGOU, CHANGEZ DE PIECE ..."
301 S$(39)="UNE AUTRE PARTIE (1=OUI/0=NON) ? "
304 S$(42)="JE SAIS QUI A TUE MONSIEUR, C'EST"
307 S$(43)="L'INDIC A ETE TUE !!! "
308 S$(44)="RETOUR AU MENU GENERAL"
310 !
313 !
316 ! PROGRAMME PRINCIPAL
319 !
322 !
325 K2=9:KL=2:FOR I=1 TO 5:BI(I)=0:L(I)=0:NEXT:TEMP=6.6
328 DIM C(20,40),M$(23),M1$(23),M2$(23)
331 GOSUB 883:GOSUB 1054:GOSUB 925:GOSUB 856
334 CALL COLOR("0M"):LOCATE (22,5):U=15:GOSUB 697
337 ACCEPT BEEP VALIDATE("01")SIZE(1)NULL(0),NA:CALL HROFF:CALL C
340 IF NA=1 THEN GOSUB 796
343 GOSUB 640
346 F(1)=10:D(1)=2:F(2)=19:D(2)=10
349 F(3)=2:D(3)=14:F(4)=2:D(4)=30
352 F(5)=19:D(5)=30
355 FOR I=1 TO N
358 IF L(I)=1 OR TEMP<=0 THEN 529
361 IF Z2=1 THEN 421 ELSE Z2=1
364 CLS "GBB":RESTORE 82:CALL COLOR("0Gb")
367 FOR J=1 TO 20:LOCATE (J,1):PRINT RPT$(" ",39):NEXT
370 FOR J=1 TO 5:READ X,Y,M,M1:GOSUB 1027:NEXT
373 FOR J=1 TO 20:READ X,Y,M:GOSUB 991:NEXT
376 FOR J=1 TO 16:READ X,Y,M:GOSUB 1009:NEXT
379 C(16,36)=3:C(6,39)=5:C(5,39)=5
382 FOR J=17 TO 18:C(J,2)=4:NEXT
385 CALL COLOR("0GB")
388 LOCATE (13,33):PRINT "CUISINE"
391 LOCATE (19,33):PRINT "G.SALON"
394 LOCATE (19,21):PRINT "P.SALON"
397 LOCATE (2,33):PRINT "VERANDA"
400 LOCATE (19,13):PRINT "BOUDOIR"
403 LOCATE (19,2):PRINT "BUREAU"
406 LOCATE (2,2):PRINT "SAM "
409 LOCATE (2,8):PRINT " WC "
412 LOCATE (2,17):PRINT "LABO "
415 LOCATE (2,23):PRINT "CAVE "
418 CALL SPEECH(Z$(3)):PAUSE 1
421 CALL COLOR("1MY"):LOCATE (16,36):PRINT "d":CALL COLOR("1WB")
424 FOR J=17 TO 18:LOCATE (J,2):PRINT "A":NEXT
427 FOR J=5 TO 6:LOCATE (J,39):PRINT "A":NEXT
430 IF C(F(I),D(I))=1 THEN CALL COLOR("1RY") ELSE CALL COLOR("1Rb")
433 LOCATE (F(I),D(I)):PRINT "a"
436 CALL COLOR("0GB"):LOCATE (22,1):PRINT RPT$(" ",39)
439 LOCATE (22,5):PRINT N$(I)
442 CALL COLOR("1BW"):! Des
445 FOR J=1 TO RND*10+5:LOCATE (22,22)
448 WE=INT(RND*6)+1:CALL SPEECH(Z$(1))
451 PRINT CHR$(9+WE):NEXT J
454 FOR J=1 TO WE
457 F1(I)=F(I):D1(I)=D(I)
460 B$(J)=KEY$
463 IF B$(J)=CHR$(128)THEN F(I)=F(I)-1
466 IF B$(J)=CHR$(130)THEN F(I)=F(I)+1
469 IF B$(J)=CHR$(131)THEN D(I)=D(I)-1
472 IF B$(J)=CHR$(129)THEN D(I)=D(I)+1
475 IF C(F(I),D(I))=2 THEN CALL SPEECH(Z$(1)):F(I)=F1(I):D(I)=D1(I)
478 IF C(F(I),D(I))=4 THEN F(I)=6:D(I)=38:BI(I)=BI(I)-1
481 IF C(F(I),D(I))=5 THEN F(I)=16:D(I)=2:BI(I)=BI(I)-1
484 IF C(F1(I),D1(I))=1 THEN CALL COLOR("0YY") ELSE CALL COLOR("0bb")
487 LOCATE (F1(I),D1(I)):PRINT " "
490 IF C(F(I),D(I))=1 THEN CALL COLOR("1RY") ELSE CALL COLOR("1Rb")
493 LOCATE (F(I),D(I)):PRINT "a":NEXT J
496 TEMP=TEMP-.11
499 CALL COLOR("0GB"):LOCATE (21,24):PRINT USING"TEMPS= #.##",TEMP
502 IF C(F(I),D(I))<>1 THEN BI(I)=0:GOTO 517
505 BI(I)=BI(I)+1:IF BI(I)<3 THEN 511 ELSE CALL COLOR("0MB")
508 LOCATE (22,5):U=25:GOSUB 697:GOTO 529
511 TR=INT(RND*100):IF TR>75 AND XW=0 THEN GOSUB 1174:GOTO 517
514 GOSUB 553:GOSUB 604
517 IF C(F(I),D(I))<>3 THEN 529
520 FOR J=50 TO 52:FOR K=140 TO 145:CALL POKE(258,J,K):PAUSE .01
523 NEXT:PAUSE .1:NEXT:CALL POKE(259,0):GOSUB 640
526 GOSUB 673:GOSUB 604:L(I)=1:GOSUB 1081:IF TEMP=0 THEN CLS
529 NEXT
532 IF TEMP>0 THEN 355 ELSE GOSUB 715:LL=0
535 GOSUB 640:FOR I=1 TO N:CALL COLOR("0GB")
538 IF L(T(I))=1 THEN LL=LL+1:GOTO 547
541 LOCATE (17,10):PRINT N$(T(I));" TA SOLUTION"
544 GOSUB 673:GOSUB 604:L(T(I))=1:GOSUB 1081
547 NEXT
550 !
553 ! QUESTION
556 !
559 CALL COLOR("0WB"):LOCATE (22,5):U=16:GOSUB 697
562 ACCEPT BEEP VALIDATE("10")SIZE(1)NULL(0),Q
565 IF Q=0 THEN 577
568 FOR J=1 TO 22:LOCATE (22,1)
571 PRINT USING 52,M1$(J),M2$(J),M$(J)
574 PAUSE 2:LOCATE (22,1):PRINT RPT$(" ",39):NEXT:GOTO 559
577 TR=INT(RND*100):IF TR<65 THEN 586
580 LOCATE (22,5):U=17:GOSUB 697
583 LOCATE (22,22):INPUT O$:GOTO 592
586 LOCATE (22,5):U=18:GOSUB 697:LOCATE (22,22):INPUT O2$
589 LOCATE (22,5):U=19:GOSUB 697:LOCATE (22,22):INPUT O1$
592 RETURN
595 !
598 ! ANALYSE
601 !
604 SC=0:IF O$=M$(A(1))THEN SC=SC+1
607 IF O1$=M1$(A(2))THEN SC=SC+1
610 IF O2$=M2$(A(3))THEN SC=SC+1
613 LOCATE (22,5)
616 IF SC=0 THEN U=20:GOSUB 697
619 IF SC=1 THEN U=21:GOSUB 697
622 IF SC=2 THEN U=22:GOSUB 697
625 IF SC=3 THEN GOSUB 1123
628 O$="":O1$="":RETURN
631 !
634 ! LISTE
637 !
640 CLS "WBB":CALL COLOR("0YH")
643 FOR K=2 TO 3:LOCATE (K,15):PRINT "LES INDICES":NEXT
646 CALL COLOR("0WB")
649 FOR K=1 TO 11:LOCATE (K+K2,1)
652 PRINT USING 52,M1$(K),M2$(K),M$(K)
655 NEXT:PAUSE:FOR K=1 TO 11:LOCATE (K+K2,1)
658 PRINT RPT$(" ",40):NEXT
661 FOR K=12 TO 22:LOCATE (K-KL,8)
664 PRINT USING 52,M1$(K),M2$(K),M$(K)
667 NEXT:K2=4:KL=7:CALL SPEECH(Z$(3)):PAUSE:RETURN
670 !
673 ! SOLUTION
676 !
679 CALL COLOR("0CB"):Z2=0
682 LOCATE (18,5):U=23:GOSUB 697:LOCATE (18,22):INPUT O$
685 LOCATE (19,5):U=18:GOSUB 697:LOCATE (19,22):INPUT O2$
688 LOCATE (20,5):U=19:GOSUB 697:LOCATE (20,22):INPUT O1$
691 RETURN
694 !
697 ! LETTRAGE
700 !
703 FOR H=1 TO LEN(S$(U)):CALL POKE(258,120,140)
706 PRINT SEG$(S$(U),H,1);:PAUSE .05:NEXT
709 CALL POKE(258,70,134):PAUSE .05:CALL POKE(259,45):RETURN
712 !
715 ! FINAL
718 !
721 FOR J=129 TO 143:CALL POKE(259,50,J):PAUSE .15:NEXT:CALL POKE(259,0)
724 S$(26)="LE TEMPS D'ENQUETE EST ECOULE."
727 S$(27)="VOUS ALLEZ UN A UN DONNER LE RESULTAT"
730 S$(28)="DE VOS RECHERCHES."
733 S$(29)="C'EST L'EXL 100 QUI DONNERA L'ORDRE"
736 S$(30)="DE PASSAGE.":CALL COLOR("0B")
739 LOCATE (2,2):PRINT RPT$(" ",38):LOCATE (3,2):PRINT RPT$(" ",38)
742 CALL COLOR("0RH")
745 FOR J=2 TO 3:LOCATE (J,13):PRINT "FIN DU TEMPS":NEXT:CALL COLOR("0WB")
748 FOR J=10 TO 14:LOCATE (J,2):PRINT RPT$(" ",38):NEXT
751 LOCATE (21,1):PRINT RPT$(" ",79)
754 FOR J=26 TO 30:LOCATE (J-16,2):U=J:GOSUB 697:NEXT:CALL COLOR("0G")
757 LOCATE (22,12):PRINT "TAPEZ SUR RETURN":PAUSE:CALL SPEECH(Z$(3))
760 T(1)=INT(RND*N)+1:IF N=1 THEN 784
763 T(2)=INT(RND*N)+1:IF T(2)=T(1)THEN 763
766 IF N=2 THEN 784
769 T(3)=INT(RND*N)+1:IF T(3)=T(1)OR T(3)=T(2)THEN 769
772 IF N=3 THEN 784
775 T(4)=INT(RND*N)+1:IF T(4)=T(1)OR T(4)=T(2)OR T(4)=T(3)THEN 775
778 IF N=4 THEN 784
781 T(5)=INT(RND*N)+1:IF T(5)=T(1)OR T(5)=T(2)OR T(5)=T(3)OR T(5)=T(4)THEN 781
784 RETURN
787 !
790 ! REGLES
793 !
796 S$(1)=" EGNIME SE JOUE A CINQ JOUEURS AU"
799 S$(2)="MAXIMUM."
802 S$(3)=" IL S'AGIT DE TROUVER AVANT LES AU-"
805 S$(4)="TRES ET EN TEMPS LIMITE, L'ASSASSIN, "
808 S$(5)="L'ARME ET LE LIEU DU CRIME."
811 S$(6)=" POUR VOUS DEPLACER,UTILISER LES TABULATEURS."
814 S$(7)=" DES QUE VOUS AVEZ LA SOLUTION, AL-"
817 S$(8)="LEZ DANS LE GRAND SALON ET TELEPHONEZ."
820 S$(9)=" LE PREMIER AURA GAGNE ..."
823 CLS "RBB":CALL COLOR("0RH"):FOR I=2 TO 3:LOCATE (I,10)
826 PRINT "LA REGLE DE EGNIME":NEXT
829 FOR I=1 TO 2:CALL COLOR("0YB"):LOCATE (I+6,1):U=I:GOSUB 697:NEXT
832 FOR I=3 TO 5:CALL COLOR("0W"):LOCATE (I+7,1):U=I:GOSUB 697:NEXT
835 LOCATE (14,1):U=6:GOSUB 697
838 FOR I=7 TO 9:CALL COLOR("0Y"):LOCATE (I+10,1):U=I:GOSUB 697:NEXT
841 LOCATE (22,10):CALL COLOR("0G"):PRINT "TAPEZ SUR RETURN"
844 CALL SPEECH(Z$(3)):PAUSE:RETURN
847 !
850 ! JOUEUR
853 !
856 FOR I=17 TO 22:LOCATE (I,1):PRINT RPT$(" ",39):NEXT
859 CALL COLOR("0MH"):FOR I=17 TO 18:LOCATE (I,5)
862 PRINT "Nbre DE JOUEURS / ";:NEXT:CALL COLOR("0Mb")
865 ACCEPT VALIDATE("12345")SIZE(1)NULL(1),N
868 CALL COLOR("0MH"):FOR I=17 TO 18:LOCATE (I,22)
871 PRINT N:NEXT:CALL COLOR("0Gb")
874 FOR I=1 TO N:LOCATE (20,10):PRINT I;" -> TON NOM : ";
877 ACCEPT VALIDATE(ALPHA)SIZE(15),N$(I):NEXT:RETURN
880 !
883 ! SON
886 !
889 Z$(1)="L,0D7C91B2BAB602FC"
892 Z$(2)="0BA02163031B18008D1E139840073"
895 Z$(2)=Z$(2)&"A108100F0901E81080480478F0"
898 Z$(2)=Z$(2)&"84420020570CEBD02110840704"
901 Z$(2)=Z$(2)&"E118840043CE0010F78C00316B"
904 Z$(2)="L,"&Z$(2)&"528"
907 Z$(3)="077C312DD46D6F708213EC60072B58C10C66308211F4A0072D6841823E9316EAB637"
910 Z$(3)=Z$(3)&"BAD18D6E74A2139DE8443BDAD18E7634A319CD66846339"
913 Z$(3)="L,"&Z$(3)&"AD18C6634A2116D684428"
916 RETURN
919 !
922 ! PRESENTATION
925 !
928 CLS "GbB":CALL HRON("B",12,4):CALL COLOR("0BB")
931 LOCATE (1,1):PRINT RPT$(" ",240);RPT$(" ",200)
934 CALL LINE("W",36,121,1,159):CALL LINE("W",284,121,319,159)
937 FOR J=121 TO 159 STEP 2:CALL LINE("W",36-H1,J,284+H1,J)
940 CALL LINE("Y",93,J,95+H1,J):H1=H1+1.84:NEXT:CALL COLOR("0CC")
943 CALL COLOR("1WB"):LOCATE (1,6):PRINT RPT$(CHR$(29),31)
946 H1=0:FOR J=1 TO 11:LOCATE (J,5):PRINT "I"
949 LOCATE (J,36):PRINT CHR$(31):NEXT
952 CALL COLOR("1RB"):RESTORE 55
955 FOR J=1 TO 5:READ X,Y,ZA$:LOCATE (X,Y):PRINT ZA$:NEXT
958 CALL COLOR("1bb")
961 FOR J=1 TO 8:READ X,Y,ZA$:LOCATE (X,Y):PRINT ZA$:NEXT
964 CALL COLOR("1MB")
967 FOR J=1 TO 8:READ X,Y,ZA$:LOCATE (X,Y):PRINT ZA$:NEXT:CALL COLOR("1C")
970 FOR J=8 TO 11:LOCATE (J,10):PRINT "AAAJ":NEXT
973 CALL COLOR("1WB"):LOCATE (16,1):PRINT RPT$(CHR$(92)&CHR$(47),20)
976 IF SZ=1 THEN RETURN
979 LOCATE (18,7):CALL COLOR("0Mb"):U=10:GOSUB 697:CALL COLOR("0Yb")
982 FOR J=11 TO 14:LOCATE (20,9):U=J:GOSUB 697:NEXT:CALL SPEECH(Z$(3))
985 PAUSE:RETURN
988 !
991 ! TRAITS HORIZONTAUX
994 !
997 CALL COLOR("1WR"):LOCATE (X,Y)
1000 PRINT RPT$(CHR$(105),M)
1003 FOR K=0 TO M-1:C(X,Y+K)=2:NEXT:RETURN
1006 !
1009 ! TRAITS VERTICAUX
1012 !
1015 FOR K=X TO X+M-1:LOCATE (K,Y)
1018 PRINT CHR$(105)
1021 C(K,Y)=2:NEXT:RETURN
1024 !
1027 ! INTERIEUR DES PIECES
1030 !
1033 FOR J1=1 TO M1:CALL COLOR("0YY")
1036 LOCATE (X+J1,Y+1):PRINT RPT$(" ",M):NEXT
1039 FOR J1=1 TO M1:FOR K=1 TO M
1042 C(X+J1,Y+K)=1:NEXT:NEXT:RETURN
1045 !
1048 ! CHOIX
1051 !
1054 RESTORE 100:FOR I=1 TO 23
1057 READ M$(I),M1$(I),M2$(I):NEXT
1060 A(1)=INT(RND*10)+1
1063 A(2)=INT(RND*23)+1
1066 IF A(2)=23 THEN A(3)=23:RETURN
1069 A(3)=INT(RND*23)+1
1072 IF A(3)=23 THEN A(2)=23
1075 RETURN
1078 !
1081 ! PERDU
1084 !
1087 PAUSE .1:CALL SPEECH(Z$(2)):LL=LL+1
1090 LOCATE (17,1):PRINT RPT$(" ",239)
1093 IF LL<N THEN PAUSE .1:RETURN
1096 GOSUB 634:CALL COLOR("0CB")
1099 LOCATE (18,5):U=23:GOSUB 697
1102 LOCATE (18,22):PRINT M$(A(1))
1105 LOCATE (19,5):U=18:GOSUB 697
1108 LOCATE (19,22):PRINT M2$(A(3))
1111 LOCATE (20,5):U=19:GOSUB 697
1114 LOCATE (20,22):PRINT M1$(A(2))
1117 LOCATE (22,5):U=24:GOSUB 697:CALL COLOR("0MB"):LOCATE (22,5):U=39:GOSUB 697
1120 ACCEPT VALIDATE("10")SIZE(1)NULL(0),Q:IF Q=1 THEN 325 ELSE END
1124 !
1126 ! GAGNE
1129 !
1132 FOR J=129 TO 143:CALL POKE(258,50,J):PAUSE .15:NEXT:CALL POKE(259,0)
1135 SZ=1:GOSUB 922
1138 S$(31)="BRAVO !!! ":S$(32)=" TU ES DIGNE DE HERCULE POIROT."
1141 S$(33)=" A BIEN TUE MONSIEUR."
1144 S$(34)="MOBILE DU CRIME : ":S$(35)="DETTE DE JEU"
1147 S$(36)="CRIME PASSIONNEL":S$(37)="VENGEANCE PERSONNELLE":SX=INT(RND*3)+1
1150 CALL COLOR("0Mb")
1153 LOCATE (17,5):U=31:GOSUB 697
1156 IF TEMP=0 THEN PRINT N$(T(I)) ELSE PRINT N$(I)
1159 U=32:GOSUB 697
1162 LOCATE (19,1):PRINT M1$(A(2));:U=33:GOSUB 697:CALL COLOR("0Wb")
1165 LOCATE (20,1):U=34:GOSUB 697:U=34+SX:GOSUB 697:CALL COLOR("0Gb")
1168 LOCATE (22,5):U=39:GOSUB 697
1171 ACCEPT VALIDATE("01")SIZE(1)NULL(0),Q:IF Q=1 THEN GOTO 322 ELSE 1121
1174 !
1177 ! EXL 100
1180 !
1183 LOCATE (22,5):TR=INT(RND*100)
1186 IF TR>35 THEN 1192 ELSE U=42:GOSUB 697:XW=1:PAUSE .1:CALL SPEECH(Z$(2))
1189 PAUSE .5:LOCATE (22,5):U=43:GOSUB 697:RETURN
1192 TR=INT(RND*22)+1:IF TR=A(2)THEN 1192
1195 TR1=INT(RND*22)+1:IF TR1=A(2)THEN 1195
1198 IF TR1=TR THEN 1195
1201 S$(38)="LORS DU MEURTRE, ":S$(40)=" ET ":S$(41)=" ETAIENT ENSEMBLE "
1204 CALL COLOR("0CB"):LOCATE (22,1):U=38:GOSUB 697:PRINT M1$(TR):PAUSE .5
1207 LOCATE (22,1):U=40:GOSUB 697:PRINT M1$(TR1);:U=41:GOSUB 697:PAUSE 1
1210 LOCATE (22,1):PRINT RPT$(" ",39):RETURN
1213 !
1216 SUB C
1219 !
1222 CALL POKE(50432,162,5,45,162,136,45,10,162,5,45,162,200,45,10)
1225 CALL EXEC(50432)
1228 SUBEND
Ce listing est uniquement proposé pour un usage privé.
Sans accord écrit préalable, vous n'êtes pas autorisé à le distribuer, le transmettre ou le rediffuser.